(* Cylindrical Coordinates *)
Manipulate[
Module[
{xx,yy,rectPoint,nRectPoint,cylPoint,pPlot,pCircle},
xx:=rr*Cos[tt];
yy:=rr*Sin[tt];
rectPoint:={xx,yy,zz};
nRectPoint:=Normalize[rectPoint];
cylPoint:={rr,tt,zz};
pPlot:=Graphics3D[{
Opacity[.25],Black,Line[{{-4,0,0},{4,0,0}}],Line[{{0,-4,0},{0,4,0}}],Line[{{0,0,-4},{0,0,4}}],
Green,Cylinder[{{0,0,-3.5},{0,0,3.5}},rr],
Opacity[1],PointSize[.025],GrayLevel[.5],Point[{0,0,0}],Red,Point[rectPoint],
Thin, Blue, Line[Sqrt[9 + rr^2]*{-nRectPoint,nRectPoint}]
}];
pCircle:= ParametricPlot3D[{rr*Cos[t],rr*Sin[t],zz},{t,0,2 Pi},PlotStyle->{Thick,Blue}];
Grid[{
{Text[Style["Rect. Coords (x,y,z): " <> ToString[NumberForm[rectPoint,{3,2}]],16]]},
{Text[Style["Cyl. Coords (r,θ,z): " <> ToString[NumberForm[cylPoint,{3,2}]],16]]},
{Show[pPlot,pCircle,ImageSize->500,Boxed->False]}
}]
],
{{rr,2,Text[Style["r:",16]]},0.1,3},
{{tt,0,Text[Style["θ:",16]]},0,2Pi},
{{zz,1,Text[Style["z:",16]]},-3,3},
ControlPlacement->Left
]

(* Spherical Coordinates *)
Manipulate[
Module[
{xx,yy,zz,rectPoint,nRectPoint,sphPoint,pPlot,pCircle1,pCircle2},
xx:=rr*Sin[pp]*Cos[tt];
yy:=rr*Sin[pp]*Sin[tt];
zz:=rr*Cos[pp];
rectPoint:={xx,yy,zz};
nRectPoint:=Normalize[rectPoint];
sphPoint:={rr,pp,tt};
pPlot:=Graphics3D[{
Opacity[.25],Black,Line[{{-4,0,0},{4,0,0}}],Line[{{0,-4,0},{0,4,0}}],Line[{{0,0,-4},{0,0,4}}],
Green,Sphere[{0,0,0},rr],
Opacity[1],PointSize[.025],GrayLevel[.5],Point[{0,0,0}],Red,Point[rectPoint],
Thin, Blue, Line[Sqrt[9 + rr^2]*{-nRectPoint,nRectPoint}]
}];
pCircle1:= ParametricPlot3D[{rr*Sin[pp]*Cos[t],rr*Sin[pp]*Sin[t],zz},{t,0,2 Pi},PlotStyle->{Thick,Blue}];
pCircle2:=ParametricPlot3D[{rr*Cos[tt]*Sin[t],rr*Sin[tt]*Sin[t],rr* Cos[t]},{t,0,2Pi},PlotStyle->{Thick,Yellow}];
Grid[{
{Text[Style["Rectangular Coords (x,y,z): " <> ToString[NumberForm[rectPoint,{3,2}]],16]]},
{Text[Style["Spherical Coords (ρ,θ,ϕ): " <> ToString[NumberForm[sphPoint,{3,2}]],16]]},
{Show[pPlot,pCircle1,pCircle2,ImageSize->500,Boxed->False]}
}]
],
{{rr,4,Text[Style["ρ:",16]]},0.1,4},
{{tt,0,Text[Style["θ:",16]]},0,2Pi},
{{pp,Pi/4,Text[Style["ϕ:",16]]},0,Pi},
ControlPlacement->Left
]

Show[
ContourPlot3D[x^2+y^2+(z-2)^2==4,{x,-3,3},{y,-3,3},{z,0,5},Mesh->False,PlotRange->{{-3,3},{-3,3},{-1,5}},ImageSize->600,AxesOrigin->{0,0,0},ContourStyle->{Opacity[0.55],Orange}],
ParametricPlot3D[{r*Cos[t],r*Sin[t],(Sqrt[(r^2/3)])},{r,0,3},{t,0,2π},Mesh->False,PlotStyle->{Opacity[0.6],Blue}]
]

Show[
ContourPlot3D[x^2+y^2+(z-2)^2==4,{x,-3,3},{y,-3,3},{z,1,5},Mesh->False,PlotRange->{{-3,3},{-3,3},{-1,5}},ImageSize->600,AxesOrigin->{0,0,0},ContourStyle->{Opacity[0.55],Orange}],
ParametricPlot3D[{r*Cos[t],r*Sin[t],(Sqrt[(r^2/3)])},{r,0,√3},{t,0,2π},Mesh->False,PlotStyle->{Opacity[0.6],Blue}]
]